Dim cnn As ADODB.Connection
Dim lngRegAfectados As Long
Dim SQL As String

' Configuramos una conexión con la base de
' datos de SQL Server, utilizando la seguridad
' integrado de Windows NT
'
Set cnn = New ADODB.Connection
With cnn
    .CursorLocation = adUseClient
    .Provider = "SQLOLEDB"
    .ConnectionString = "Data Source=NOMBRE_INSTANCIA_SQL_SERVER;" & _
        "Initial Catalog=Northwind;" & _
        "Integrated Security=SSPI;"
    .Open
End With

' Si la tabla ya existe en la base de datos de
' SQL Server, la eliminamos
'
cnn.Execute _
    "IF EXISTS(" & _
        "SELECT * FROM INFORMATION_SCHEMA.TABLES " & _
        "WHERE TABLE_NAME = 'TablaDeAccess')" & _
    "DROP TABLE TablaDeAccess", , adCmdText

' Construimos la consulta SQL de creación de tabla para
' importar la tabla Clientes de la base de datos Neptuno.mdb
'
SQL = "SELECT * INTO TablaDeAccess " & _
      "FROM OPENROWSET(" & _
        "'Microsoft.Jet.OLEDB.4.0'," & _
        "'C:\Mis documentos\Neptuno.mdb';" & _
        "'admin';''," & _
        "'SELECT * FROM Clientes')"

' Ejecutamos la consulta
'
cnn.Execute SQL, lngRegAfectados, adCmdText

' Comprobamos los registros afectados
'
MsgBox "Registros afectados: " & lngRegAfectados

' Cerramos la conexión
'
cnn.Close